it-swarm-ko.tech

Excel 통합 문서의 모든 피벗 테이블을 매크로로 새로 고침

20 가지 피벗 테이블이있는 통합 문서가 있습니다. 모든 피벗 테이블을 찾아 VBA에서 새로 고치는 쉬운 방법이 있습니까?

78
Lipis

예.

ThisWorkbook.RefreshAll

또는 Excel 버전이 충분히 오래된 경우

Dim Sheet as WorkSheet, Pivot as PivotTable
For Each Sheet in ThisWorkbook.WorkSheets
    For Each Pivot in Sheet.PivotTables
        Pivot.RefreshTable
        Pivot.Update
    Next
Next
161
GSerg

이 VBA 코드는 통합 문서의 모든 피벗 테이블/차트를 새로 고칩니다.

Sub RefreshAllPivotTables()

Dim PT As PivotTable
Dim WS As Worksheet

    For Each WS In ThisWorkbook.Worksheets

        For Each PT In WS.PivotTables
          PT.RefreshTable
        Next PT

    Next WS

End Sub

프로그래밍이 아닌 다른 옵션은 다음과 같습니다.

  • 각 피벗 테이블을 마우스 오른쪽 버튼으로 클릭하십시오.
  • 테이블 옵션 선택
  • '새로 고침' 옵션을 선택하십시오.
  • 확인 버튼을 클릭하십시오

통합 문서를 열 때마다 피벗 테이블이 새로 고쳐집니다.

26
Robert Mearns

ActiveWorkbook.RefreshAll은 피벗 테이블뿐만 아니라 _ ​​ODBC 쿼리도 모두 새로 고칩니다. 데이터 연결을 참조하는 두 개의 VBA 쿼리가 있는데이 옵션을 사용하면 명령이 VBA에서 제공 한 세부 정보없이 데이터 연결을 실행할 때 충돌이 발생합니다.

피벗 만 새로 고치려면 옵션을 권장합니다

Sub RefreshPivotTables()     
  Dim pivotTable As PivotTable     
  For Each pivotTable In ActiveSheet.PivotTables         
    pivotTable.RefreshTable     
  Next 
End Sub 
20
Kevin

특정 상황에서 피벗 테이블과 해당 피벗 캐시를 구별 할 수 있습니다. 캐시에는 자체 새로 고침 방법과 자체 컬렉션이 있습니다. 따라서 피벗 테이블 대신 모든 피벗 캐시를 새로 고칠 수있었습니다.

차이점? 새 피벗 테이블을 만들면 이전 테이블을 기반으로 원하는 피벗 테이블이 있는지 묻습니다. 아니요라고 말하면이 피벗 테이블은 자체 캐시를 가져와 소스 데이터 크기를 두 배로 늘립니다. 예라고 대답하면 WorkBook을 작게 유지하지만 단일 캐시를 공유하는 피벗 테이블 모음에 추가합니다. 해당 컬렉션에서 단일 피벗 테이블을 새로 고치면 전체 컬렉션이 새로 고쳐집니다. 따라서 통합 문서의 모든 피벗 테이블을 새로 고치는 것과 비교하여 통합 문서의 모든 캐시를 새로 고치는 것의 차이점이 무엇인지 상상할 수 있습니다.

8
Steve WahWah Weeks

피벗 테이블 도구 모음에는 모두 새로 고침 옵션이 있습니다. 충분합니다. 다른 작업을 수행 할 필요가 없습니다.

Ctrl + Alt + F5를 누릅니다.

5
Prasenjit

VB Worksheet 개체에 PivotTables 컬렉션이 있습니다. 따라서 이와 같은 빠른 루프가 작동합니다.

Sub RefreshPivotTables()
    Dim pivotTable As PivotTable
    For Each pivotTable In ActiveSheet.PivotTables
        pivotTable.RefreshTable
    Next
End Sub

참호의 메모 :

  1. 피벗 테이블을 업데이트하기 전에 보호 된 시트를 보호 해제해야합니다.
  2. 자주 저장.
  3. 더 많은 것을 생각하고 적시에 업데이트 할 것입니다 ... :)

행운을 빕니다!

1
LohanJ

심지어 특정 연결을 새로 고칠 수 있음 그리고 연결된 모든 피벗을 새로 고칩니다.

이 코드에서는 Excel에있는 표에서 슬라이서를 만들었습니다 :

Sub UpdateConnection()
        Dim ServerName As String
        Dim ServerNameRaw As String
        Dim CubeName As String
        Dim CubeNameRaw As String
        Dim ConnectionString As String

        ServerNameRaw = ActiveWorkbook.SlicerCaches("Slicer_ServerName").VisibleSlicerItemsList(1)
        ServerName = Replace(Split(ServerNameRaw, "[")(3), "]", "")

        CubeNameRaw = ActiveWorkbook.SlicerCaches("Slicer_CubeName").VisibleSlicerItemsList(1)
        CubeName = Replace(Split(CubeNameRaw, "[")(3), "]", "")

        If CubeName = "All" Or ServerName = "All" Then
            MsgBox "Please Select One Cube and Server Name", vbOKOnly, "Slicer Info"
        Else
            ConnectionString = GetConnectionString(ServerName, CubeName)
            UpdateAllQueryTableConnections ConnectionString, CubeName
        End If
    End Sub

    Function GetConnectionString(ServerName As String, CubeName As String)
        Dim result As String
        result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
        '"OLEDB;Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False"
        GetConnectionString = result
    End Function

    Function GetConnectionString(ServerName As String, CubeName As String)
    Dim result As String
    result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
    GetConnectionString = result
End Function

Sub UpdateAllQueryTableConnections(ConnectionString As String, CubeName As String)
    Dim cn As WorkbookConnection
    Dim oledbCn As OLEDBConnection
    Dim Count As Integer, i As Integer
    Dim DBName As String
    DBName = "Initial Catalog=" + CubeName

    Count = 0
    For Each cn In ThisWorkbook.Connections
        If cn.Name = "ThisWorkbookDataModel" Then
            Exit For
        End If

        oTmp = Split(cn.OLEDBConnection.Connection, ";")
        For i = 0 To UBound(oTmp) - 1
            If InStr(1, oTmp(i), DBName, vbTextCompare) = 1 Then
                Set oledbCn = cn.OLEDBConnection
                oledbCn.SavePassword = True
                oledbCn.Connection = ConnectionString
                oledbCn.Refresh
                Count = Count + 1
            End If
        Next
    Next

    If Count = 0 Then
         MsgBox "Nothing to update", vbOKOnly, "Update Connection"
    ElseIf Count > 0 Then
        MsgBox "Update & Refresh Connection Successfully", vbOKOnly, "Update Connection"
    End If
End Sub
0
Rajiv Singh

코드

Private Sub Worksheet_Activate()
    Dim PvtTbl As PivotTable
        Cells.EntireColumn.AutoFit
        For Each PvtTbl In Worksheets("Sales Details").PivotTables
        PvtTbl.RefreshTable
        Next
End Sub 

잘 작동합니다.

코드는 시트 활성화 모듈에 사용되므로 시트가 활성화되면 깜박임/글리치가 표시됩니다.

0
user3564681